Transmission and Reflection from a Square Well

Niels Walet

Description

We investigate the reflection and transmission from a square barrier, of width a and height (Subscript[V, 0]).

Plot[If[Abs[x]<1,1,0],{x,-2,2},PlotStyle->Hue[0.0]]

The Schrodinger equation in the three regions I: x<-a, II: -a<x<a, and III: x>a can easily be written down,
I, III -((ℏ^2)/(2m))((d^2)/(dx^2))ϕ(x)=E ϕ(x),
II:-((ℏ^2)/(2m))((d^2)/(dx^2))ϕ(x)+(Subscript[V, 0])ϕ(x)=E ϕ(x).
We shall solve these equations for 0<E<(Subscript[V, 0]). 
Argue that in that case the solution in regions I and III are oscillatory (complex exponents), and in region II is exponential (or the sum of hyperbolic functions). 
Define k = (Sqrt[((2m)/(ℏ^2))E]), κ=(Sqrt[((2m)/(ℏ^2))((Subscript[V, 0])-E)]). Is this a sensible definition?

Solving for R and T.

Just to be sure, make k,κ,(Subscript[A, 1]),(Subscript[B, 1]),(Subscript[B, 2]),(Subscript[A, 3])undefined. When they are not defined this gives some error messages...

k=.;κ=.;(Subscript[A, 1])=.;(Subscript[B, 1])=.;(Subscript[B, 2])=.;(Subscript[A, 3])=.;

Define the wave functions in regions I, II and III. We have an incoming and reflected wave  in region I, the full solution in region II, and only a transmitted wave in region III

(Subscript[ϕ, I])[x_]:=(Subscript[A, 1]) (E^(I k x))+(Subscript[B, 1]) (E^(-I k x));
(Subscript[ϕ, II])[x_]:=(Subscript[A, 2]) Cosh [κ x]+(Subscript[B, 2]) Sinh [κ x];
(Subscript[ϕ, III])[x_]:=(Subscript[A, 3]) (E^(I k x));

Set up the four matching equations, for the functions and their derivatives at x=±a.

eqns1=(Subscript[ϕ, I])[-a]==(Subscript[ϕ, II])[-a];
eqns2=(Subscript[ϕ, II])[a]==(Subscript[ϕ, III])[a];
eqns3=(((Subscript[ϕ, I])))'[-a]==(((Subscript[ϕ, II])))'[-a];
eqns4=(((Subscript[ϕ, II])))'[a]==(((Subscript[ϕ, III])))'[a];
eqns={eqns1,eqns2,eqns3,eqns4}

Solve the equations. Can you derive the solution yourself? Why don't I solve for (Subscript[A, 1])?

solution=Simplify[Solve[eqns,{(Subscript[A, 3]),(Subscript[B, 1]),(Subscript[A, 2]),(Subscript[B, 2])}]]

The next statement removes one of the pair of curly brackets

substitution=Flatten[solution];

Transmission Coefficient

And we now calculate the complex quantity that enters the transmission coefficient,

sqT=((Subscript[A, 3])/(Subscript[A, 1]))/.substitution

Unfortunately, the easiest way to get a maneagable expression for Rand T  is to take the numerator and denominator, and multiply those with their complex conjugates. ComplexExpand than assumes that all variables are real, and Simplify generates a simpler version of the result.

TransmissionCoefficient=Simplify[((ComplexExpand[Numerator[sqT] Conjugate[Numerator[sqT]]])/(ComplexExpand[Denominator[sqT] Conjugate[Denominator[sqT]]]))]

Reflection Coefficient

We now calculate the complex quantity that enters the reflection coefficient,

sqR=((Subscript[B, 1])/(Subscript[A, 1]))/.substitution

ReflectionCoefficient=Simplify[((ComplexExpand[Numerator[sqR] Conjugate[Numerator[sqR]]])/(ComplexExpand[Denominator[sqR] Conjugate[Denominator[sqR]]]))]

Check

We now check our calculation, and show that R+T=1.

Simplify[TransmissionCoefficient+ReflectionCoefficient]

Plots

We now shall make some plots. Before doing so we realise that R and T depend on k a and κ a only. Furthermore we have κ a =  (Sqrt[((((Subscript[κ, 0])a))^2)-(((k a))^2) ]), with (Subscript[κ, 0])=(Sqrt[((2m)/(ℏ^2))(Subscript[V, 0])]). We shall investigate R and T as function of k a.

Rka=ReflectionCoefficient/.κ->((Sqrt[((((Subscript[κ, 0]) a))^2)-(((k a))^2)])/a);Tka=TransmissionCoefficient/.κ->((Sqrt[((((Subscript[κ, 0]) a))^2)-(((k a))^2)])/a);

(Subscript[κ, 0])a=1

Plot[{Rka/.{a->1,(Subscript[κ, 0])->1},Tka/.{a->1,(Subscript[κ, 0])->1}},{k,0,1},PlotStyle->{Hue[0.0],Hue[0.6]},AxesLabel->{"k","R or T"}]

(Subscript[κ, 0])a=2

Plot[{Rka/.{a->2,(Subscript[κ, 0])->1},Tka/.{a->2,(Subscript[κ, 0])->1}},{k,0,1},PlotStyle->{Hue[0.0],Hue[0.6]},AxesLabel->{"k","R or T"}]

(Subscript[κ, 0])a=1/2

Manipulate[Plot[{Rka/.{a->κa,(Subscript[κ, 0])->1},Tka/.{a->κa,(Subscript[κ, 0])->1}},{k,0,1},PlotStyle->{Hue[0.0],Hue[0.6]},AxesLabel->{"k","R or T"}],{κa,0.1,2}]

Assignments

Solve for R and T for E>(Subscript[V, 0])(Following the schema above). Provide graphs for the same three values of (Subscript[κ, 0])a.

Hints: What is the wave function in region II? What are allowed values of  k a?

Change the barrier into a well, i.e., (Subscript[V, 0])->-(Subscript[V, 0])(Following the schema above). Provide graphs for the same three values of (Subscript[κ, 0])a.

Hints: What is the wave function in region II? What are allowed values of  k a?